Intégrer License Guard dans vos robots MQL5

#include <JAson.mqh>   // Optionnel : parsing JSON

#define ROBOT_NAME "Systest"  // 🔒 Nom du robot verrouillé

long   allowedAccountId       = 0;     // ID du compte autorisé
string licenseKey             = "";
string url                    = "https://secure.fullmargin.net/scripts/validate.php";
string headers                = "Content-Type: application/x-www-form-urlencoded\r\n";
int    LICENSE_CHECK_INTERVAL = 1800;  // 30 minutes

// Input à déclarer dans votre EA
input string licenseKeyInput = ""; // Saisissez votre clé de licence ici

// --------- Fichiers licence ---------
string GetLicenseFileName()
{
   string eaName = MQLInfoString(MQL_PROGRAM_NAME);
   return eaName + "_license.txt";
}

bool SaveLicenseToFile(string license)
{
   string filename = GetLicenseFileName();
   int fileHandle  = FileOpen(filename, FILE_WRITE | FILE_TXT);
   if(fileHandle == INVALID_HANDLE)
   {
      Print("Erreur d'écriture dans le fichier ", filename);
      return false;
   }
   FileWrite(fileHandle, license);
   FileClose(fileHandle);
   return true;
}

string LoadLicenseFromFile()
{
   string filename = GetLicenseFileName();
   int fileHandle  = FileOpen(filename, FILE_READ | FILE_TXT);
   if(fileHandle == INVALID_HANDLE)
   {
      Print("Fichier ", filename, " introuvable.");
      return "";
   }
   string savedLicense = FileReadString(fileHandle);
   FileClose(fileHandle);
   return savedLicense;
}

// --------- Vérifier la licence auprès du serveur ---------
bool CheckLicense()
{
   if(licenseKey == "")
   {
      Print("Aucune clé de licence définie.");
      return false;
   }

   string postData = "licenseKey=" + licenseKey + "&robotName=" + ROBOT_NAME;

   char data[];
   StringToCharArray(postData, data);

   char   response[];
   string responseHeaders;
   int    timeout = 5000;

   int res = WebRequest("POST", url, headers, timeout, data, response, responseHeaders);

   if(res == 200)
   {
      string responseBody = CharArrayToString(response);
      Print("Réponse du serveur : ", responseBody);

      int validIndex = StringFind(responseBody, "\"valid\":");
      if(validIndex != -1)
      {
         bool isValid = (StringSubstr(responseBody, validIndex + 8, 4) == "true");
         if(isValid)
         {
            Print("Licence valide.");
            return true;
         }
         else
         {
            Print("Licence invalide ou expirée.");
         }
      }
      else
      {
         Print("Réponse JSON invalide : champ \"valid\" introuvable.");
      }
   }
   else
   {
      Print("Erreur de connexion au serveur. Code d'erreur : ", res);
   }

   return false;
}

// --------- Timer de vérification ---------
void StartLicenseCheckTimer()
{
   if(LICENSE_CHECK_INTERVAL > 0)
      EventSetTimer(LICENSE_CHECK_INTERVAL);
}

void StopLicenseCheckTimer()
{
   EventKillTimer();
}

// OnTimer est appelé automatiquement par MetaTrader
void OnTimer()
{
   if(!CheckLicense())
   {
      Print("Licence invalide lors de la vérification périodique. Le robot sera arrêté.");
      ExpertRemove();
   }
}